C# と VB.NET の質問掲示板

Windows11/VB2017を趣味で楽しんでる素人です。
場所違いでしたらご容赦ください。

実行中にフリーズ等がする起因の程はようやく分かったのですが、
これを今あるプログラムにどのように当てはめれば良いのかが分からずにいます。
FunctionやSubは有っても良いのですが、原型は出来るだけ崩さずにする方法があればお願いを致します。

      Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
        ProgressBar1.Minimum = 0
        ProgressBar1.Maximum = 1000
        ProgressBar1.Value = 0
        Label1.Text = "0"

        For i = 0 To 1000
            'ここに時間のかかる処理 　　（※ この場所は変えずにお願いします）
            System.Threading.Thread.Sleep(10)

            ProgressBar1.Value = i
            Me.Refresh()
            Label1.Text = i

        Next
    End Sub

■No102522 (WebSurfer さん) に返信

> Studio 2017 で、ターゲットフレームワークを .NET Framework 4.5 以降で作
> っていると想像して。（そういうことは最初に質問に書きましょうね）
Windows11はてっきり .NET Framework 4.5 以降と思っていました。

> 解決策は非同期プログラミングです。
そのようです。

時間のかかる処理はFor〜Nextの中に書きたくも思っています。
>       Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
>         ProgressBar1.Minimum = 0
>         ProgressBar1.Maximum = 1000
>         ProgressBar1.Value = 0
>         Label1.Text = "0"
> 
>         For i = 0 To 1000
>             'ここに時間のかかる処理 　　（※ この場所は変えずにお願いします）
>             System.Threading.Thread.Sleep(10)
> 
>             ProgressBar1.Value = i
>             Me.Refresh()
>             Label1.Text = i
> 
>         Next

これでいいのでは？

Private Async Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
    ProgressBar1.Minimum = 0
    ProgressBar1.Maximum = 1000
    ProgressBar1.Value = 0
    Label1.Text = "0"
    Await Task.Run(
        Sub()
            For i = 0 To 1000
                System.Threading.Thread.Sleep(10)
                Invoke(
                    Sub(index As Integer)
                        ProgressBar1.Value = index
                        Label1.Text = index.ToString()
                        Me.Refresh()
                    End Sub, i)
            Next
        End Sub)
End Sub

■No102529 (KOZ) に返信
こういう形でもいいんでしょうけどメチャ遅くなりそう

For i = 0 To 1000
    Await Task.Run(
        Sub()
            System.Threading.Thread.Sleep(10)
        End Sub)
    ProgressBar1.Value = i
    Label1.Text = i.ToString()
    Me.Refresh()
Next

■No102530 (KOZ さん) に返信

何故かこれはエラーが出てしまいましたが、No102529ので十分ではあります。

    Private Async Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
        ProgressBar1.Minimum = 0
        ProgressBar1.Maximum = 1000
        ProgressBar1.Value = 0
        Label1.Text = "0"
        Await Task.Run(
            action:=Async Sub()
                        For i = 0 To 1000
                            Await Task.Run(
        Sub()
            System.Threading.Thread.Sleep(10)
        End Sub)
                            ProgressBar1.Value = i
                            Label1.Text = i.ToString()
                            Me.Refresh()              '< ---ここに「ユーザーが処理していない例外」が出る
                        Next     
                    End Sub)
    End Sub

> ■No102529 (KOZ) に返信
> こういう形でもいいんでしょうけどメチャ遅くなりそう
> 
> For i = 0 To 1000
>     Await Task.Run(
>         Sub()
>             System.Threading.Thread.Sleep(10)
>         End Sub)
>     ProgressBar1.Value = i
>     Label1.Text = i.ToString()
>     Me.Refresh()
> Next
> 

■No102535 (KOZ さん) に返信

ありがとうございます。
No102529ので十分ですのでそちらを使わせていただきます。

それとこれはProgressBar1.Valueを直接設定したもですが、これも同じように可能でしょうか？

    Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
        ProgressBar1.Minimum = 0
        ProgressBar1.Maximum = 100
        ProgressBar1.Value = 0
        Label1.Text = "0"
        Me.Refresh()

        System.Threading.Thread.Sleep(500)   'ここに時間のかかる処理 　
        ProgressBar1.Value = 25
        Me.Refresh()
        Label1.Text = 25.ToString()

        System.Threading.Thread.Sleep(500)   'ここに時間のかかる処理 　
        ProgressBar1.Value = 50
        Me.Refresh()
        Label1.Text = 50.ToString()

        System.Threading.Thread.Sleep(500)   'ここに時間のかかる処理 
        ProgressBar1.Value = 75
        Me.Refresh()
        Label1.Text = 75.ToString()

        System.Threading.Thread.Sleep(500)   'ここに時間のかかる処理 　
        ProgressBar1.Value = 100
        Me.Refresh()
        Label1.Text = 100.ToString()
  
   End Sub

■No102537 (焼いも さん) に返信
> ■No102535 (KOZ さん) に返信
> ありがとうございます。
> No102529ので十分ですのでそちらを使わせていただきます。
> それとこれはProgressBar1.Valueを直接設定したもですが、これも同じように可能でしょうか？

下記のようにすればできるはずです。
UIスレッド、別スレッド、invoke、Async、Awaitをきちんと学ばないと、
応用問題ができなくなります。
基礎を学ぶことを強くお勧めします。

※下記ではinvoke出てきていませんが、必要な知識です。
※Button1_Click内の処理はUIスレッド上で実行されます。
※Task.Run内の処理は別スレッド上で実行されます。
※Awaitがあると、処置が完了するまで、UIスレッドをブロックすることなく
　Button1_Click内の処理を一時中断します。
※上記言葉が技術的ではないところもありますが、イメージとしてとらえてください。

    Private Async Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
        ProgressBar1.Minimum = 0
        ProgressBar1.Maximum = 100
        ProgressBar1.Value = 0
        Label1.Text = "0"
        Me.Refresh()

        Await Task.Run(
            Sub()
                System.Threading.Thread.Sleep(500)   'ここに時間のかかる処理
            End Sub)
        ProgressBar1.Value = 25
        Label1.Text = 25.ToString()
        Me.Refresh()

       以下、上記と同様に修正

        System.Threading.Thread.Sleep(500)   'ここに時間のかかる処理 　
        ProgressBar1.Value = 50
        Me.Refresh()
        Label1.Text = 50.ToString()

        System.Threading.Thread.Sleep(500)   'ここに時間のかかる処理 
        ProgressBar1.Value = 75
        Me.Refresh()
        Label1.Text = 75.ToString()

        System.Threading.Thread.Sleep(500)   'ここに時間のかかる処理 　
        ProgressBar1.Value = 100
        Me.Refresh()
        Label1.Text = 100.ToString()
  
   End Sub

■No102529 (KOZ さん) に返信

これは凄い！
もう諦めてただけにメチャクチャ嬉しいです。
30分近くも掛かる処理なので尚更です。

申し訳ないのですが、もしよかったら関連してのもう一つお願いは出来ないでしょうか？
それは「Label2.Text = "テスト"」のとこで下のエラーがことです。

> ユーザーが処理していない例外
> System.InvalidOperationException: '有効ではないスレッド間の操作: コントロールが作成されたスレッド以外のスレッドからコントロール 'Label2' がアクセスされました。

    Private Async Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
        ProgressBar1.Minimum = 0
        ProgressBar1.Maximum = 1000
        ProgressBar1.Value = 0
        Label1.Text = "0"
        Await Task.Run(
            Sub()
                For i = 0 To 1000
                    System.Threading.Thread.Sleep(10)
                    Call test()

                    Invoke(
                        Sub(index As Integer)
                            ProgressBar1.Value = index
                            Label1.Text = index.ToString()
                            Me.Refresh()
                        End Sub, i)
                Next
            End Sub)
    End Sub

    'ここでもう一つの作業を実施
    Private Sub test()
        Label2.Text = "テスト"        '< ---ここに「ユーザーが処理していない例外」が出る
    End Sub