C# と VB.NET の質問掲示板

何故、「RadioButtonの初期設定」の後に、再びfrmchild.Show()まで戻るのかを教えてください。
戻らずにその次への「Private Sub RadioButton1_CheckedChanged・・」へと進みたいのです。
ちなみに「RadioButtonの初期設定」の部分を削除すれば、そうなります。


Public Class Form1
    Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
        'このフォームを MDI コンテナとして設定 
        Me.IsMdiContainer = True
    End Sub

    '子フォームを開く
    Private Sub スタートToolStripMenuItem_Click(sender As Object, e As EventArgs) Handles スタートToolStripMenuItem.Click
        Dim frmchild As New Form2
        frmchild.MdiParent = Me
        frmchild.Show()
    End Sub
End Class


Public Class Form2
    Private Sub Form2_Load(sender As Object, e As EventArgs) Handles MyBase.Load

        'RadioButtonの初期設定 
        RemoveHandler RadioButton1.CheckedChanged, AddressOf RadioButton1_CheckedChanged
        RadioButton1.Checked = True
        AddHandler RadioButton1.CheckedChanged, AddressOf RadioButton1_CheckedChanged

        Stop    '動作の確認の為、一旦止める。
    End Sub     'ここから何故か frmchild.Show()　に戻るのが不思議です。

    Private Sub RadioButton1_CheckedChanged(sender As Object, e As EventArgs) Handles RadioButton1.CheckedChanged

    End Sub
End Class

Friend WithEvents RadioButton1 As RadioButton

Private Sub RadioButton1_CheckedChanged(sender As Object, e As EventArgs) Handles RadioButton1.CheckedChanged

End Sub

このように書くと、WidthEvent をつけたフィールドはプロパティとしてコンパイルされ、次の様になります。

Private _RadioButton1 As RadioButton

Friend Property RadioButton1 As RadioButton
    Get
        Return _RadioButton1
    End Get
    Set(value As RadioButton)
        If _RadioButton1 IsNot Nothing Then
            RemoveHandler _RadioButton1.CheckedChanged, AddressOf RadioButton1_CheckedChanged
        End If
        _RadioButton1 = value
        If _RadioButton1 IsNot Nothing Then
            AddHandler _RadioButton1.CheckedChanged, AddressOf RadioButton1_CheckedChanged
        End If
    End Set
End Property

Private Sub RadioButton1_CheckedChanged(sender As Object, e As EventArgs) ' Handles は無くなる

End Sub

なので次のコードを実行すると

RemoveHandler RadioButton1.CheckedChanged, AddressOf RadioButton1_CheckedChanged  'イベントが解除される
RadioButton1.Checked = True                                                       '値が変更されても飛ばない 
AddHandler RadioButton1.CheckedChanged, AddressOf RadioButton1_CheckedChanged     '変更された後なので飛ばない

ということになります。