C# と VB.NET の質問掲示板

■No102514 (カルミーア さん) に返信

>>TabControlを自分でビジュアルスタイルで描画する
>>https://dobon.net/vb/dotnet/control/tabsidebug.html#paint
>>が参考になると思います。
> こちらせっかく御紹介頂き申し訳ないですが、面倒というよりも目的と剥離しているような気がしました。
> タブの回転などは全く不要で、必要な部分が何なのかがよくわからない状況です。

コピペして文字を描いているところだけ修正すればいいんですが・・・

> 加えてこちらのサンプルは色をべた塗しておりますが、私が求めるものはデフォルトと同じグレーのグラデーション色です。
> グレーのグラデーション色に設定しているものをご提示頂けると大変ありがたいです。

コピペして実行してみました？

>>面倒なら TabPage 実際の文字列は Tag プロパティに保存しておいて、Text プロパティはスペースで埋めておいて文字列のみ描画すればいいかも。
> ソースコードを提示してくださってありがとうございます。
> ただ、私の要求が正直こんなに手の込んだものになるとは思わず、かなり難航しています。
> ビットマップ形式のファイルが必要？みたいですが、そうなってくると開発陣や顧客に相談しないといけなくなります。

ファイルは不要です。耳の位置は上固定でいいなら簡単です。
TabPage の Tag プロパティに表示する文字、Text プロパティには相応の空白を設定してください。

Public Class CustomTabControl
    Inherits TabControl

    Public Sub New()
        DoubleBuffered = True
        ResizeRedraw = True
        SetStyle(ControlStyles.UserPaint, False)
    End Sub

    Const WM_PAINT = &HF

    Protected Overrides Sub WndProc(ByRef m As Message)
        Select Case m.Msg
            Case WM_PAINT
                SetStyle(ControlStyles.UserPaint, True)
                MyBase.WndProc(m)
                SetStyle(ControlStyles.UserPaint, False)
            Case Else
                MyBase.WndProc(m)
        End Select
    End Sub

    Protected Overrides Sub OnPaint(e As PaintEventArgs)
        Dim hdc = e.Graphics.GetHdc()
        Dim m = Message.Create(Handle, WM_PAINT, hdc, IntPtr.Zero)
        DefWndProc(m)
        e.Graphics.ReleaseHdc()
        For i As Integer = 0 To TabPages.Count - 1
            Dim page As TabPage = TabPages(i)
            Dim rect As Rectangle = GetTabRect(i)
            Dim tabColor As Color
            Dim tabFont As Font
            Dim needDispose As Boolean = False
            If i = SelectedIndex Then
                tabColor = Color.Red
                tabFont = New Font(Font.FontFamily, Font.Size, FontStyle.Bold)
                needDispose = True
            Else
                tabColor = ForeColor
                tabFont = Font
            End If
            TextRenderer.DrawText(e.Graphics, CStr(page.Tag),
                                  tabFont, rect, tabColor,
                                  TextFormatFlags.HorizontalCenter Or TextFormatFlags.VerticalCenter)
            If needDispose Then
                tabFont.Dispose()
            End If
        Next
        MyBase.OnPaint(e)
    End Sub

End Class