C# と VB.NET の質問掲示板

LINQがつかえるなら、まずDistinctで含まれる元素のリストを作ってから
それぞれについてカウントすればよいと思います。

================================================

Dim source As String() = New String() {"O", "Ca", "O", "O", "O", "Ca", "Ca", "Ca", "Ca"}

'含まれる元素のリスト
Dim elementList = source.Distinct()

'含まれる元素ごとに集計
Dim result As New List(Of String)
For Each element As String In elementList
    Dim count As Integer = source.Count(Function(c) c = element)
    result.Add(element & "=" & count)
Next

'表示
Console.WriteLine(String.Join(", ", result))

えい！

Dim symbols = {"O", "O", "Ca"}

Console.WriteLine(symbols _
    .GroupBy(Function(symbol) symbol) _
    .Select(Function(group) String.Format("{0}={1}", group.Key, group.Count())) _
    .Aggregate(Function(a, b) a & "," & b))

ありがとうございます。
うまくいきました。

ぼーちゃんさんの方法の方がシンプルな気がしますので
こちらを使いたいと思います。

ところで、配列に関してですが
実際には文字列配列ではなく


    Public Class EleInfo

        Property Components As String
	’元素ごとの情報が入ったクラス

    End Class


    Dim source(1000) As EleInfo

のようにして宣言したクラスを使っています。

この場合どのようにしたら良いですか？

自分で改良してみたのですが
これだとうまくいきませんでした。


        '含まれる元素のリスト
        Dim elementList As IEnumerable = source.Distinct()

        '含まれる元素ごとに集計
        Dim result As New List(Of String)
        For Each element As EleInfo In elementList
            Dim count As Integer = source.Count(Function(c) c = element.Components)
            result.Add(element.Components & "=" & count)
        Next

        MsgBox(String.Join(", ", result))

> 自分で改良してみたのですが
> これだとうまくいきませんでした。

まずSelectを使って「sourceの集合」から「source.Componentsの集合」へ射影（変換）してください
(意味が分からない場合は是非Selectについて調べてみてください〜)
あとはその射影に対して同じようにDistinctやCountを実行すればいいです

=============================================================================================================

'含まれる元素のリスト
Dim elementList = source.Select(Function(d) d.Components).Distinct()

'含まれる元素ごとに集計
Dim result As New List(Of String)
For Each element As String In elementList
    Dim count As Integer = source.Select(Function(s) s.Components).Count(Function(c) c = element)
    result.Add(element & "=" & count)
Next

MsgBox(String.Join(", ", result))

ただ、行数で言えばもりおさんのやり方の方がシンプルですね
クラス配列の場合でも

>.GroupBy(Function(symbol) symbol)
を
.GroupBy(Function(symbol) symbol.Components)

にするだけで対応できるはずです