C# と VB.NET の質問掲示板

            Dim DateMod(1000) As Date
            Dim filepath(1000) As String

というような配列を宣言し、
DateModの日時順で
複数の配列をソートしたいのですが
普通にやるなら以下のように一つずつ地道にする方法があります。

配列が二つくらいなら良いですが
これが10個とか20個になってくると
コードが見づらいですし、
後からの修正も大変ですので
もっとスマートな書き方をしたいのですが何か良い方法はありますでしょうか？




            For i = 1 To 1000

                For j As Integer = 1000 To i Step -1

                    If DateMod(i) > DateMod(j)  Then

                        Dim swap1 As Date = DateMod(i)
                        DateMod(i) = DateMod(j)
                        DateMod(j) = swap1

                        Dim swap2 As String = filepath(i)
                        filepath(i) = filepath(j)
                        filepath(j) = swap2

                    End If
                Next j
            Next i

■No85978 (こんなのお さん) に返信

なちゃさんの言うようにデータをクラス化してひとまとめにして扱うのがよいと思いますが
提示された内容をいかしておこなうなら以下のような方法もあります。

a,bがデータです。他にあっても全然かまいません。
sortidxsがbをソートとした結果の配列のインデックスの配列となります。(実際にはbはソートされません)
sortidxsに設定されている順番にa,bから該当する要素を取り出せばそれはbをソートした順番に取り出せることになります。
sortidxsを求めるときのOrder Byの部分を変更すればaでのソートをすることもその他の配列でソートすることもできます。

        Dim a = {5, 2, 1, 6, 21, 4}
        Dim b = {#2017/10/1#, #2017/10/2#, #2017/10/10#, #2017/10/5#, #2017/10/8#, #2017/10/3#}

        Dim sortidxs = (From idx In Enumerable.Range(0, a.Length)
                        Order By b(idx)).ToArray

        For idx = 0 To sortidxs.Length - 1
            Dim idx2 = sortidxs(idx)
            Console.WriteLine($"{a(idx2)} {b(idx2)}")
        Next

■No85985 (こんなのお さん) に返信

クラスを使うならLINQに丸投げしちゃいましょう

Class Item
    Public Property DateMod As Date
    Public Property filepath As String
End Class

Sub Main()
    Dim Data = {
        New Item() With {.DateMod = New Date(2017, 12, 3), .filepath = "c:\a.txt"},
        New Item() With {.DateMod = New Date(2017, 12, 2), .filepath = "c:\b.txt"},
        New Item() With {.DateMod = New Date(2017, 12, 1), .filepath = "c:\c.txt"}
    }

    Dim dateSorted = Data.OrderBy(Function(item) item.DateMod)

    For Each item In dateSorted
        Console.WriteLine(item.filepath)
    Next

    Console.ReadKey()
End Sub